Estimating Parameters using SAEM

PumasEMModels can optionally be fitted using SAEM. Here is an example PumasEMModel definition:

using Pumas
using PumasUtilities
using Random

covariate_saem_cov = @emmodel begin
    @random begin
        CL ~ 1 + logwt | LogNormal
        v ~ 1 | LogNormal
    end
    @covariance 2
    @covariates wt
    @pre begin
        Vc = wt * v
    end
    @dynamics Central1
    @post begin
        cp = Central / Vc
    end
    @error begin
        dv ~ ProportionalNormal(cp)
    end
end

PumasEMModel
 Parameters with random effects: 
	CL ~ (1, :logwt) | LogNormal
	v ~ (1,) | LogNormal
  Covariates: wt
  Pre-dynamical variables: Vc
  Dynamical system variables: Central
  Post-dynamical variables: cp

See the documentation on the @emmodel macro interface for an explanation of the syntax. To fit this model, we'll simulate data using simobs.

sim_params_covariate_cov = (;
    CL = (4.0, 0.75),
    v = 70.0,
    Ω = (Pumas.@SMatrix([0.1 0.05; 0.05 0.1]),),
    σ = ((0.2,),),
)

obstimes = 0.0:100.0

dose = DosageRegimen(1_000; addl = 2, ii = 24)

function choose_covariates()
    wt = (55 + 25rand()) / 70
    return (; wt, logwt = log(wt))
end

pop = [Subject(; id = i, events = dose, covariates = choose_covariates()) for i = 1:72]
sims = simobs(
    covariate_saem_cov,
    pop,
    sim_params_covariate_cov;
    obstimes,
    ensemblealg = EnsembleSerial(),
)
reread_df = DataFrame(sims);

pop_covariate = read_pumas(reread_df; observations = [:dv], covariates = [:logwt, :wt])

Population
  Subjects: 72
  Covariates: logwt, wt
  Observations: dv

When specifying inits, it is not necessary to specify any variance parameters for the random effects or error models.

init_covariate = (; CL = (2.0, 2 / 3), v = 50.0)

(CL = (2.0, 0.6666666666666666),
 v = 50.0,)

If unspecified, they will be initialized to 1.0 or the identity matrix for covariances. SAEM's stochastic exploration phase is most effective when these variance parameters are much larger than the true variances. Thus, if the true variances are believed to be around 1.0 or larger, it is recommended to specify larger initial values manually.

It is possible to pass a vector of random number generates as an argument to fit. If so, the fit will use one thread per RNG. By specifying the seeds of each RNG, SAEM() can be fully reproducible:

rngv = [MersenneTwister(1941964947i + 1) for i ∈ 1:Threads.nthreads()];

fit_covariate_cov1 = fit(
    covariate_saem_cov,
    pop_covariate,
    init_covariate,
    SAEM();
    ensemblealg = EnsembleThreads(),
    rng = rngv,
)

rngv = [MersenneTwister(1941964947i + 1) for i ∈ 1:Threads.nthreads()];

fit_covariate_cov2 = fit(
    covariate_saem_cov,
    pop_covariate,
    init_covariate,
    SAEM();
    ensemblealg = EnsembleThreads(),
    rng = rngv,
)

coef(fit_covariate_cov1) == coef(fit_covariate_cov2) # true

true

One can also specify the number of iterations for each of the three phases (rapid exploration, convergence, smoothing):

fit_covariate_cov =
    fit(covariate_saem_cov, pop_covariate, init_covariate, SAEM(; iters = (1000, 500, 500)))

FittedPumasEMModel

Likelihood approximation:                     SAEM
Dynamical system type:                 Closed form

Log-likelihood value:                   -11978.649
Number of subjects:                             72
Number of parameters:         Fixed      Optimized
                                  0              7
Observation records:         Active        Missing
    dv:                        7272              0
    Total:                     7272              0

-------------------
         Estimate
-------------------
CL₁       3.7787
CL₂       0.45985
v        64.149
Ω₁,₁      0.072998
Ω₂,₁      0.050007
Ω₂,₂      0.11089
σ         0.20191
-------------------

The results of a fit can be analyzed normally:

infer_cov = infer(fit_covariate_cov)

Asymptotic inference results using sandwich estimator

Likelihood approximation:                     SAEM
Dynamical system type:                 Closed form

Log-likelihood value:                   -11978.649
Number of subjects:                             72
Number of parameters:         Fixed      Optimized
                                  0              7
Observation records:         Active        Missing
    dv:                        7272              0
    Total:                     7272              0

--------------------------------------------------------------------
            Estimate           SE                     95.0% C.I.
--------------------------------------------------------------------
CL_base      3.7787          0.14408          [ 3.4963  ;  4.0611 ]
CL_logwt     0.45985         0.24405          [-0.018474;  0.93817]
v_base      64.149           2.5374           [59.176   ; 69.122  ]
ω_1₁,₁       0.27018         0.020669         [ 0.22967 ;  0.31069]
ω_1₂,₁       0.18509         0.035352         [ 0.1158  ;  0.25438]
ω_1₂,₂       0.27683         0.021897         [ 0.23391 ;  0.31975]
σ_0          0.20191         0.0016972        [ 0.19858 ;  0.20523]
--------------------------------------------------------------------

coeftable(infer_cov)

inspect_cov = inspect(fit_covariate_cov)

[ Info: Calculating predictions.
[ Info: Calculating weighted residuals.
[ Info: Calculating empirical bayes.
[ Info: Evaluating individual parameters.
[ Info: Evaluating dose control parameters.
[ Info: Done.